ssolv.F90

Go to the documentation of this file.

!-------------------------------------------------------------------
!-------------------------------------------------------------------
SUBROUTINE settolv
  use kinds, only : dp
  use size_m, only : nx1, ny1, nz1
  use eigen, only : eigaa, eigas
  use input, only : iftran, ifnav
  use soln, only : vdiff, vtrans
  use tstep, only : ifield, nelfld, istep, tolabs, dt, vnrml8, vnrmsm 
  use tstep, only : tolps, tolrel, tolhv, tolhr, tolhs, tolpdf
  implicit none

  REAL(DP) :: avvisc, avdens, vnorm, factor
  integer :: ntot
  real(DP), external :: glmin, glmax

  ntot   = nx1*ny1*nz1*nelfld(ifield)
  avvisc = glmin(vdiff(1,1,1,1,ifield),ntot)
  avdens = glmax(vtrans(1,1,1,1,ifield),ntot)

  vnorm = 0.
  IF (iftran) THEN
      IF (istep == 1)  vnorm = vnrml8
      IF (istep > 1)  vnorm = vnrmsm
      IF (vnorm == 0.) vnorm = tolabs
      factor = 1.+(avdens/(eigaa*avvisc*dt))
  ELSE
      vnorm = vnrml8
      IF (vnorm == 0.) vnorm = tolabs
      factor = 1.
  ENDIF

  tolps  = tolrel*vnorm * sqrt(eigas)/(4.*factor)
  tolhv  = tolrel*vnorm * sqrt(eigaa)*avvisc/2.
  tolhv  = tolhv/3.
  IF ( .NOT. iftran .AND. .NOT. ifnav) tolhv = tolhv/10.
  tolhr  = tolhv
  tolhs  = tolhv

!   Non-zero default pressure tolerance
!   NOTE: This tolerance may change due to precision problems.
!         See subroutine CHKSSV

  IF (tolpdf /= 0.) tolps = tolpdf

  RETURN
END SUBROUTINE settolv

!-------------------------------------------------------------------
!-------------------------------------------------------------------
SUBROUTINE settolt
  use kinds, only : dp
  use size_m, only : nx1, ny1, nz1
  use eigen, only : eigaa
  use input, only : iftran
  use soln, only : vdiff
  use tstep, only : ifield, nelfld, istep, tnrml8, tnrmsm, tolabs, tolht, tolrel
  implicit none

  REAL(DP) :: avcond, tnorm
  integer :: ntot
  real(DP), external :: glmin

  ntot   = nx1*ny1*nz1*nelfld(ifield)
  avcond = glmin(vdiff(1,1,1,1,ifield),ntot)

  tnorm = 0.
  IF (iftran) THEN
      IF (istep == 1)  tnorm = tnrml8(ifield-1)
      IF (istep > 1)  tnorm = tnrmsm(ifield-1)
      IF (tnorm == 0.) tnorm = tolabs
  ELSE
      tnorm = tnrml8(ifield-1)
      IF (tnorm == 0.) tnorm = tolabs
  ENDIF

  tolht(ifield) = tolrel*tnorm * sqrt(eigaa)*avcond

  RETURN
END SUBROUTINE settolt

!-----------------------------------------------------------------------
!----------------------------------------------------------------------
SUBROUTINE setchar
  use kinds, only : dp
  use size_m, only : nid
  use input, only : ifchar
  use tstep, only : ctarg, ntaubd
  implicit none

  integer :: ict
  real(DP) :: rict, dct

  IF (ifchar) THEN
      ict    = int(ctarg)
      rict   = (ict)
      dct    = ctarg-rict
      IF (dct == 0.) ntaubd = ict
      IF (dct > 0.) ntaubd = ict+1
  !        if (param(78).ne.0) then
  !             ntaupf=int(param(78))
  !             if (nid.eq.0) write(6,*) ' new ntaubd:',ntaubd,ntaupf
  !             ntaubd=max(ntaubd,ntaupf)
  !        endif
  ELSE
      ntaubd = 0
      IF (ctarg > 0.5) THEN
          IF (nid == 0) &
          WRITE (6,*) 'Reset the target Courant number to .5'
          ctarg = 0.5
      ENDIF
  ENDIF

  RETURN
END SUBROUTINE setchar